Wednesday Workshop - BlitzCoder.net

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|512|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-
simple algebra game

by Edmund for Workshop #123
Catch the correct algebra as it falls.
Mouse
;Well, this code is a disaster and an optimization nighmare.

;If anyone is learning to code, don't learn from me.

;drop me a comment if you read this

;simple algebra game v. 1.2

;3 11 2007

;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;read me;;;;;;;;;;;;;;

;ever wish you could practice doing simple algebra?

;me neither

;but here's how you play the game

;use the mouse to move your player (that number in the <{}>)

;catch equations that your number completes to get points

;the higher your number is, the more points you get

;once you catch an equation, your number changes (or it should)

;if you don't catch the wrong equation, you lose points

;if an equation that your number completes falls to the bottom of the screen, you lose points

;the game gets harder as you keep playing

;there is a cheat to be used when you're frustrated

;it's somewhere in the code

;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;

Const ScreenWidth=640, ScreenHeight=480 ;set up basics

SetBuffer BackBuffer()

SeedRnd MilliSecs()

Graphics screenwidth, screenheight

;create variables

Global score = 0

Global timer

Global chance = 25



;types

Type player

	Field x

	Field y

	Field image$

	Field id

End Type



Type number

	Field id$

	Field x

	Field y

	Field speed

	Field score

End Type



Type point

	Field x

	Field y

	Field image$

	Field time

End Type

;types over



;build player

Global player.player = New player

	player\x = MouseX()

	player\y = MouseY()

;build over



;menu loop

While Not KeyHit(3)

	Cls

	Text 250,80,"The Numbers Game"

	Text 250,140,"by Edmund"

	Text 250,180,"hit 1 to learn to play"

	Text 250,200,"hit 2 to begin game"

	Flip

	If KeyHit(3) ;exit menu

		Exit

	EndIf

	While KeyDown (2) ;view instructions

		Cls

		Text 10,40,"20*x = 80"

		Text 400,120,"25/x = 5"

		Text 300,180,"4*x = 24"

		Text 200,350,"<{5}>  < == that's you"

		Text 0,0,"score : 50"

		Text 0,420,"this is what the game looks like, catch the equation that your number completes

		Text 0,440,"To gain more points.  If you miss a fitting equation, you lose points"

		Text 0,460,"(search the code for a cheat)"

		Flip

		Delay 50

	Wend

Wend



Cls ;make sure this menu gets wiped

Flip

Cls

FlushKeys()



;get the difficulty level

Global difficulty =  Input$("enter the maximum number you want the game to reach (difficulty) :")

player\id = 1

player\image = "<{" + player\id + "}>"



;mainloop

While Not KeyHit(1)

	Cls

	;create new numbers

	timer = timer + 1

	If timer > chance

		timer = 0

		Newnumber()

	EndIf

	;create numbers over

	;call functions

	updatepoint()

	updatenumber()

	updateplayer()

	writeworld() ; cheat in this function

	;call over

	Flip

	Delay 50

Wend



;create a new number, give it a random position and generate a random equation

Function newnumber()

	number.number = New number

		number\x = Rand(10,500)

		number\y = - 10

		firstnum = Rand(1,difficulty)

		whathappens = Rand(1,3)

		If whathappens = 1 ; multiplication

			secondnum = Rand(1,difficulty)

			thirdnum = firstnum*secondnum

			number\id$ = secondnum + "* x" + "=" + thirdnum

		EndIf

		If whathappens = 2 ;division

			secondnum = Rand(1,difficulty)

			thirdnum = firstnum*secondnum

			number\id$ = thirdnum + "/ x" + "=" + secondnum

		EndIf

		If whathappens = 3 ;subtraction

			secondnum = Rand(1,difficulty*2)

			thirdnum = secondnum - firstnum

			number\id$ = secondnum + "- (" + thirdnum + ")= x"

		EndIf

		number\score = firstnum

		number\speed = Rand(1,3)

End Function



;move the numbers down, if they fall pass the bottom, delete them

Function updatenumber()

	For number.number = Each number

		number\y = number\y + number\speed

		If number\y > screenheight - 5

			If number\score = player\id

				score = score - number\score

				newpoint(number\score,2,number\x,number\y)

			EndIf

			Delete number

		EndIf

	Next

End Function



;update player position, find if there is player number contact, if so compute out come

Function updateplayer()

	player\x = MouseX()

	player\y = MouseY()

	For number.number = Each number ;should be moved to the updatenumber function

		If player\x < number\x + 70 And player\x + 50 > number\x And player\y < number\y + 20 And player\y + 20 > number\y

			If number\score = player\id

				score = score + number\score ;add to score

				player\id = Rand(1,difficulty - 1)

				player\image = "<{" + player\id + "}>"

				newpoint(number\score,1,number\x,number\y)

				difficulty = difficulty + 1

				Delete number

			Else

				score = score - number\score ;take from score

				newpoint(number\score,2,number\x,number\y)

				Delete number

			EndIf

		EndIf

	Next

End Function



;draw player, number, point, and score

Function writeworld()

	Text player\x,player\y,player\image

	For number.number = Each number

		If KeyDown(57) ; <--- cheat here

			Text number\x,number\y - 10,number\score

		EndIf

		Text number\x,number\y,number\id

	Next

	For point.point = Each point

		Text point\x,point\y,point\image

	Next

	Text 0,0,"score: " + score

End Function



;create a new point (number indicated, 1 = position 2 = negative, x of point, y of point)

Function newpoint(num,form,x,y)

	point.point = New point

	point\x = x

	point\y = y

	If form = 1

		point\image$ = "( plus " + num + " score )"

	EndIf

	If form = 2

		point\image$ = "( minus " + num + " score )"

	EndIf

	point\time = 50

End Function



;move the point up and delete it when it's time runs out

Function updatepoint()

	For point.point = Each point

		point\y = point\y - 1

		point\time = point\time - 1

		If point\time < 0

			Delete point

		EndIf 

	Next

End Function