Wednesday Workshop - BlitzCoder.net

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|554|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Line Squares

by Jayenkai for Workshop #062

Move the mouse into the squares to score.

Mouse

Graphics 800,600,32,2
SetBuffer BackBuffer()

HidePointer()
SeedRnd MilliSecs()

HighCombo=0
HighScore=0



SaveScores=0
;Set to 1 if you'd like to save your highscores.
SaveDir$="system/062/"
;But make sure this directory exists..


SaveFile$="highscore.dat"
If savescores=1
	If FileType(savedir+savefile)=1
		quicky=ReadFile(savedir+savefile)
		highcombo=ReadInt(quicky)
		highscore=ReadInt(quicky)
		CloseFile quicky
	EndIf
EndIf


ML=20
Score=0
Font=LoadFont("Arial",26)
SetFont font

Type ox
Field x
Field y
Field col
Field Time
End Type


Type bos
Field x
Field y
Field col
Field digit
Field time
End Type


MyCol=0
MyCombo=0

Dim LC#(ML,2)



.MainMenu
Repeat
Cls
Color 255,255,255

Text 400,50,"Line Squares",1,1
Color 255,0,0
Text 400,200,"Move the mouse into the squares to score.",1,1
Text 400,250,"Get the same colors to score combos.",1,1
Color 0,255,0
Text 400,400,"High Score : "+HighScore,1,1
Text 400,450,"Best Combo : "+HighCombo,1,1

If MouseDown(1) Then Gosub StartRound

Flip
Until KeyDown(1)


End


.StartRound
For n=1 To ML
LC#(n,1)=400:LC#(n,2)=300
Next
For b.ox=Each ox:Delete b.ox:Next
For com.bos=Each bos:Delete com.bos:Next

CenterX=400
CenterY=300

EndTime=MilliSecs()+60000

Repeat
Cls
;CopyRect 10,0,790,600,0,0

For n=1 To ML-1
LC(n,1)=LC(n+1,1)
LC(n,2)=LC(n+1,2)

LC(n,1)=LC(n,1)-((LC(n,1)-CenterX)/(n+1))
LC(n,2)=LC(n,2)-((LC(n,2)-CenterY)/(n+1))
Next

CenterX=LC(1,1)
CenterY=LC(1,2)

LC(ML,1)=MouseX()
LC(ML,2)=MouseY()

For n=0 To ML-1
If MyCol=0 Then Color n*12,n*12,n*12
If MyCol=1 Then Color n*12,180,180
If MyCol=2 Then Color 180,n*12,180
If MyCol=3 Then Color 180,180,n*12
If n=0 Then Line CenterX,CenterY,lC(n+1,1),LC(n+1,2)
If n>0 Then Line LC(n,1),lc(n,2),lC(n+1,1),LC(n+1,2)
Next

Text 400,10,Score,1,1

Timeleft=EndTime-MilliSecs()

Text 400,580,Millisecstotime(Timeleft),1,1
If Timeleft<0 Then endofgame=1


If Rand(1,25)=1
Repeat
X=Rand(0,800):Y=Rand(0,600)
fin=0
If Abs(X-MouseX())>100 And Abs(Y-MouseY())>100 Then fin=1
Until fin=1

B.ox=New ox
B\x=x:b\y=y
b\col=Rand(1,3)
b\time=Rand(150,200)
If b\col=mycol Then b\time=Rand(SCom,SCom+50)
EndIf


For b.ox=Each ox
If b\Col=1 Then Color 255,100,100
If b\Col=2 Then Color 100,255,100
If b\Col=3 Then Color 100,180,255
Rect b\x-(b\time/8),b\y-(b\time/8),b\time/4,b\time/4,0

b\time=b\time-1
kill=0
If b\time=0 Then kill=1
If mousein((b\x-(b\time/4))-2,(b\y-(b\time/4))-2,(b\time/2)+4,(b\time/2)+4)
If b\col=MyCol Then mycombo=mycombo+1:score=score+b\time+(Combo*10):If SCom>20 Then SCom=SCom-10
If b\col<>MyCol Then mycombo=1:mycol=b\col:score=score+b\time:SCom=100
kill=1
com.bos=New bos
com\x=b\x
com\y=b\y
com\col=b\col
com\digit=mycombo
com\time=30
EndIf


If kill=1 Then Delete b.ox
Next


For com.bos=Each bos
If com\Col=1 Then Color 255,100,100
If com\Col=2 Then Color 100,255,100
If com\Col=3 Then Color 100,100,255
com\time=com\time-1
kill=0
If com\time=0 Then kill=1

Text com\x,com\y,com\digit,1,1
If kill=1 Then Delete com.bos
Next

If MyCombo>HighCombo Then HighCombo=MyCombo
If Score>HighScore Then HighScore=Score


Flip
If KeyDown(1) Then endofgame=99
Until endofgame<>0

If savescores=1
		quicky=WriteFile(savedir+savefile)
		WriteInt(quicky,Highcombo)
		WriteInt(quicky,Highscore)
		CloseFile quicky
EndIf


Return


Function mousein(x1,y1,wide,high)
If MouseX()=>x1 And MouseX()<=x1+wide And MouseY()=>y1 And MouseY()<=y1+high Then Return True
End Function


Function millisecstotime$(mills,hron=0,minon=0,secon=1,milson=1)
out$=""
millsecs=(mills Mod 1000)/10
mills=(mills/1000)
secs=mills Mod 60
mills=(mills/60)
mins=mills Mod 60
mills=(mills/60)
If hron=1 Then out$=out$+xdigitstring$(mills,2)+":"
If minon=1 Then out$=out$+xdigitstring$(mins,2)+":"
If secon=1 Then out$=out$+xdigitstring$(secs,2)+":"
If milson=1 Then out$=out$+xdigitstring$(millsecs,2)


Return out$
End Function

Function xdigitstring$(integer,digits)
curstring$=Str$(integer)
If Len(curstring$)>digits Then curstring$=Right(curstring$,digits)
If Len(curstring$)<digits
noed=digits-Len(curstring$)
curstring$=String$("0",noed)+Str$(curstring$)
EndIf
Return curstring$
End Function