Wednesday Workshop - BlitzCoder.net

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|554|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Bisexual Tron

by Ryan Moody for Workshop #001

Tron!

Cursors

Graphics 640,480
SetBuffer FrontBuffer()
SeedRnd(MilliSecs())

Type Player

	Field X
	Field Y
	Field Colour$
	Field Direction$
	
End Type

Function InitialiseGame()

	Delay 2000

	Delete Each Player

	p.Player = New Player
	p\X = 30
	p\Y = 240
	p\Colour = "Red"
	P\Direction = "Right"

	p.Player = New Player
	p\X = 610
	p\Y = 240
	p\Colour = "Yellow"
	P\Direction = "Left"

	Color 50,255,0
	Rect 0,0,640,480
	Color 0,100,0
	Rect 10,10,620,460

End Function

Function UpdateGame()

	For p.Player = Each Player
	
		Select p\Direction
		
			Case "Up"		p\Y = p\Y - 1
			Case "Right"	p\X = p\X + 1
			Case "Down"		p\Y = p\Y + 1
			Case "Left"		p\X = p\X - 1
		
		End Select
	
		GetColor p\X, p\Y
	
		If p\Colour = "Red"
		
			If ColorRed() <> 0
			
				Color 255,255,255
				Text 320,20,"RED LOSES",True
				InitialiseGame()
				Exit
			
			EndIf
			
			If KeyDown(200) Then p\Direction = "Up"
			If KeyDown(203) Then p\Direction = "Left"
			If KeyDown(205) Then p\Direction = "Right"
			If KeyDown(208) Then p\Direction = "Down"
		
		Else
		
			If ColorRed() <> 0
			
				Color 255,255,255
				Text 320,20,"YELLOW LOSES",True  
				InitialiseGame()
				Exit
			
			EndIf 
		
			Select p\Direction
		
				Case "Up"		
				
					GetColor p\X, p\Y - 1 
					If ColorRed() <> 0 Then p\Direction = "Right"	
				
				Case "Right"
				
					GetColor p\X + 1, p\Y 
					If ColorRed() <> 0 Then p\Direction = "Down"
				
				Case "Down"
				
					GetColor p\X, p\Y + 1 
					If ColorRed() <> 0 Then p\Direction = "Left"

				Case "Left"
				
					GetColor p\X - 1, p\Y 
					If ColorRed() <> 0 Then p\Direction = "Up"
		
			End Select
		
		EndIf
	
	Next

End Function

Function RenderGame()

	For p.Player = Each Player
	
		If p\Colour = "Red"
		
			Color 255, 0, 0 
		
		Else
		
			Color 255, 255, 0 
				
		EndIf 
	
		Plot p\X, p\Y
	
	Next

End Function

InitialiseGame()

While Not KeyDown(1)

	UpdateGame()
	RenderGame()
	
	Delay 10

Wend

Jailbreak

by Ryan Moody for Workshop #005

Can

AppTitle "Jailbreak", "Quit Jailbreak?"

Graphics 640,480,16,2

Const MapDimensions = 7

Dim Map$(MapDimensions,MapDimensions)

Global xPos
Global yPos

Type TItem

	Field Name$
	Field Description$

End Type

Type TQuestion

	Field Place$
	Field Person$
	Field Question$

End Type

Function PrintText( theText$, colour$, newLine )

	Select colour
	
		Case "white"	Color 255,255,255
		Case "yellow"	Color 255,255,0
		Case "red"		Color 255,0,0
		Case "green"	Color 0,255,0
		Case "pink"		Color 255,200,200
		Case "cyan"		Color 0,255,255
	
	End Select

	If newLine 
	
		Print theText
		
	Else
	
		Write theText
		
	EndIf

End Function

Function PrintInventory()

	Local carryingSomething = False

	PrintText( "You are carrying:", "white", True )	

	For item.TItem = Each TItem
	
			PrintText( item\Name, "green", False )
			PrintText( " - ", "red", False )
			PrintText( item\Description, "cyan", True )
			carryingSomething = True
			
	Next
	
	If Not carryingSomething
	
		PrintText( "Nothing", "pink", True )
	
	EndIf

End Function

Function PrintArea()

	Select Map(xPos,yPos)
	
		Case "A"
		
			PrintText("You're locked in your cell. You see the", "white", False)
			PrintText(" lock ", "cyan", False)
			PrintText("preventing your escape,", "white", True)
			PrintText("along with the", "white", False)
			PrintText(" guard ", "cyan", False)
			PrintText("holding the", "white", False)
			PrintText(" key ", "cyan", False)
			PrintText("to unlock your cell a distance away.", "white", True)
			PrintText("Opposite you, you see a fellow", "white", False)
			PrintText(" inmate", "cyan", False)
			PrintText(".", "white", True)
			
		Case "B"
		
			PrintText("You're in your now unlocked cell. You see the", "white", False)
			PrintText(" lock ", "cyan", False)
			PrintText("on the floor.", "white", True)
			PrintText("The passage of the cell block lies to the north.", "white", True)

		Case "C"
		
			PrintText("You're in your now unlocked cell.", "white", True)
			PrintText("The passage of the cell block lies to the north.", "white", True)
		
		Case "D"
		
			PrintText("You're in the cell block passageway. To the south is the cell you came from.", "white", True)
			PrintText("To the east is the sleeping guard, and to the west appears to be an escape", "white", True)
			PrintText("route. Your fellow", "white", False)
			PrintText(" inmate ", "cyan", False)
			PrintText("is locked up opposite you. You see the inmate's", "white", True)
			PrintText("cell's", "white", False)
			PrintText(" lock", "cyan", False)
			PrintText(".", "white", True)
			
		Case "E"
		
			PrintText("You're to the west of your cell. You notice a small", "white", False)
			PrintText(" tile", "cyan", True)
			PrintText("on the floor that looks slightly different to the rest.", "white", True)
			PrintText("To the west is certain escape, but you decide against leaving", "white", True)
			PrintText("without your inmate. To the east is your cell.", "white", True)
		
		Case "F"
		
			PrintText("You're to the east of your cell. The guard is sleeping nearby.", "white", True)
			PrintText("You notice a", "white", False)
			PrintText(" hatch ", "cyan", False)
			PrintText("in the wall, but there appears to be no way of opening it.", "white", True)
			PrintText("To the west is your cell.", "white", True)
		
		Case "G"
		
			PrintText("You're to the west of your cell.", "white", True)
			PrintText("To the west is certain escape, but you decide against leaving", "white", True)
			PrintText("without your inmate. To the east is your cell.", "white", True)
		
		Case "H"
		
			PrintText("You're to the east of your cell. The guard is sleeping nearby.", "white", True)
			PrintText("The hatch which once concealed a", "white", False)
			PrintText(" gold key ", "cyan", False)
			PrintText("is now open.", "white", True)
			PrintText("To the west is your cell.", "white", True)
			
		Case "I"
		
			PrintText("You're to the east of your cell. The guard is sleeping nearby.", "white", True)
			PrintText("To the west is your cell.", "white", True)	

	End Select

End Function

Function MoveNorth()

	If Map(xPos,yPos - 1) <> "#"
	
		PrintText("You move North", "white", True)
		yPos = yPos - 1
		PrintArea()
	
	Else
	
		PrintText("You cannot move North", "pink", True)
		
	EndIf

End Function

Function MoveSouth()

	If Map(xPos,yPos + 1) <> "#"
	
		PrintText("You move South", "white", True)
		yPos = yPos + 1
		PrintArea()
	
	Else
	
		PrintText("You cannot move South", "pink", True)
		
	EndIf

End Function

Function MoveEast()

	If Map(xPos + 1,yPos) <> "#"
	
		PrintText("You move East", "white", True)
		xPos = xPos + 1
		PrintArea()
	
	Else
	
		PrintText("You cannot move East", "pink", True)
		
	EndIf

End Function

Function MoveWest()

	If Map(xPos - 1,yPos) <> "#"
	
		PrintText("You move West", "white", True)
		xPos = xPos - 1
		PrintArea()
	
	Else
	
		PrintText("You cannot move West", "pink", True)
		
	EndIf

End Function

Function Examine( objectToExamine$ )

	Select Map(xPos,yPos)
	
		Case "A"
		
			Select objectToExamine
			
				Case "LOCK" 
				
					PrintText("The lock's too tough to break. You'll need the key to unlock it.", "white", True)
				
				Case "GUARD" 
				
					PrintText("The guard's as ugly as hell. But at least he has freedom.", "white", True)

				Case "KEY" 
				
					PrintText("If that doesn't unlock this cell, nothing will.", "white", True)
					
				Case "INMATE" 
				
					PrintText("He faces the same fate as me. I can't let him die here.", "white", True)

				Default
				
					PrintText("I can't examine that.", "pink", True)
			
			End Select
		
		Case "B"
		
			Select objectToExamine
			
				Case "LOCK" 
				
					PrintText("Not the lightest of locks, unsurprisingly.", "white", True)
			
				Default
				
					PrintText("I can't examine that.", "pink", True)
			
			End Select
		
		Case "D"
		
			Select objectToExamine
			
				Case "INMATE" 
				
					PrintText("He's still locked up.", "white", True)
					
				Case "LOCK" 
				
					PrintText("Looks just like the lock for my cell.", "white", True)
			
				Default
				
					PrintText("I can't examine that.", "pink", True)
			
			End Select
			
		Case "E"
		
			Select objectToExamine
			
				Case "TILE" 
				
					PrintText("On closer inspection, it looks like some sort of pressure pad.", "white", True)

				Default
				
					PrintText("I can't examine that.", "pink", True)
			
			End Select

		Case "F"
		
			Select objectToExamine
			
				Case "HATCH" 
				
					PrintText("It's hiding something, but I can't open it.", "white", True)

				Default
				
					PrintText("I can't examine that.", "pink", True)
			
			End Select

		Case "H"
		
			Select objectToExamine
			
				Case "GOLD KEY" 
				
					PrintText("This must open the inmate's cell.", "white", True)

				Default
				
					PrintText("I can't examine that.", "pink", True)
			
			End Select

		Default
		
			PrintText("I can't examine that.", "pink", True)
		
	End Select

End Function

Function Take( objectToTake$ )

	Select Map(xPos,yPos)
	
		Case "A"
		
			Select objectToTake
			
				Case "KEY"
				
					PrintText("It's out of reach.", "white", True)
				
				Default
				
					PrintText("I can't take that.", "pink", True)
			
			End Select
			
		Case "B"
		
			Select objectToTake
			
				Case "LOCK"
				
					PrintText("You take the lock.", "white", True)

					i.TItem = New TItem
					i\Name = "LOCK"
					i\Description = "Not the lightest of locks, unsurprisingly."
				
					Map(xPos,yPos) = "C"
					PrintArea()
				
				Default
				
					PrintText("I can't take that.", "pink", True)
			
			End Select
			
		Case "E"
		
			Select objectToTake
			
				Case "TILE"
				
					PrintText("You can't move it.", "white", True)
				
				Default
				
					PrintText("I can't take that.", "pink", True)
			
			End Select	
		
		Case "H"
		
			Select objectToTake
			
				Case "GOLD KEY"
				
					PrintText("You take the gold key.", "white", True)
					
					i.TItem = New TItem
					i\Name = "GOLD KEY"
					i\Description = "This must open the inmate's cell."
				
					Map(xPos,yPos) = "I"
					PrintArea()
				
				Default
				
					PrintText("I can't take that.", "pink", True)
			
			End Select	
			
		Default
		
			PrintText("I can't take that.", "pink", True)
		
	End Select

End Function

Function Use( objectToUse$ )

	Select Map(xPos,yPos)
	
		Case "A"
		
			Select objectToUse
							
				Case "KEY ON LOCK"
				
					If HaveItem("KEY")
				
						PrintText("You unlock your cell, and the", "white", False)
						PrintText(" lock ", "cyan", False)
						PrintText("falls to the ground.", "white", True)
						
						Map(xPos,yPos) = "B"
						Map(xPos,Ypos-1) = "D"
						Delete Each TQuestion
						
						question.TQuestion = New TQuestion
						question\Place    = "D"
						question\Person   = "INMATE"
						question\Question = "I'M FREE!"
						
						PrintArea()
						
					Else
				
						PrintText("You don't have the key!", "pink", True)
					
					EndIf	
				
				Default
				
					PrintText("Use what on what?", "pink", True)
			
			End Select
		
		Case "D"
		
			Select objectToUse
							
				Case "KEY ON LOCK"
						
					PrintText("It doesn't fit this lock.", "white", True)
					
				Case "GOLD KEY ON LOCK"
						
					PrintText("You free the inmate from his cell! You both dash westwards", "white", True)
					PrintText("towards the escape! JAILBREAK!!!", "white", True)
					
					Delay 1000
					FlushKeys
					WaitKey
					End
				
				Default
				
					PrintText("Use what on what?", "pink", True)
			
			End Select
		
		Case "E"
		
			Select objectToUse
							
				Case "LOCK ON TILE"
					
					If HaveItem("LOCK")
						
						PrintText("You place the lock on the tile, and you see something open to the east.", "white", True)
						PrintText("It must have been a pressure pad.", "white", True)
					
						DeleteItem("LOCK")
						Map(xPos,yPos) = "G"
						Map(xPos + 2,yPos) = "H"
						PrintArea()
						
					Else
					
						PrintText("Use what on what?", "pink", True)
					
					EndIf
				
				Default
				
					PrintText("Use what on what?", "pink", True)
			
			End Select
		
		Default
				
			PrintText("Use what on what?", "pink", True)
		
	End Select

End Function

Function HaveItem( theItem$ )

	For item.TItem = Each TItem
	
		If item\Name = theItem Then Return True
	
	Next

	Return False

End Function

Function DeleteItem( theItem$ )

	For item.TItem = Each TItem
	
		If item\Name = theItem Then Delete item
	
	Next

End Function

Function TalkTo( person$ )

	Select person
	
		Case "GUARD"
		
			Select Map(xPos,yPos)
							
				Case "A"
				
					Conversation( Map(xPos,yPos), person )
				
				Default
				
					PrintText("Talk to who?", "pink", True)
			
			End Select
		
		Case "INMATE"
		
			Select Map(xPos,yPos)
							
				Case "A","D"
				
					Conversation( Map(xPos,yPos), person )
				
				Default
				
					PrintText("Talk to who?", "pink", True)
			
			End Select
		
		Default
				
			PrintText("Talk to who?", "pink", True)
		
	End Select

End Function

Function Conversation( place$, person$ )

	Local questionNo = 1
	Local choice
	Local validChoice = False

	PrintText("What do you want to say?", "white", True)

	For question.TQuestion = Each TQuestion
	
		If question\Place = place And question\Person = person
		
			PrintText(questionNo + ": " + question\Question, "cyan", True)
			questionNo = questionNo + 1
		
		EndIf 
	
	Next
	
	PrintText(questionNo + ": Exit conversation", "cyan", True)
	PrintText("Enter a number: ", "yellow", False)
	
	choice = Input()	
	questionNo = 1
	
	For question.TQuestion = Each TQuestion
	
		If question\Place = place And question\Person = person
		
			If questionNo = choice
			
				validChoice = True
				Response(place, person, question\Question)

			EndIf
			
			questionNo = questionNo + 1

		EndIf 
	
	Next
	
	If (Not validChoice) And (choice <> questionNo)
	
		PrintText("Enter one of the given numbers.", "pink", True)
				
	EndIf

	If choice <> questionNo
	
		Conversation( place, person )

	Else
	
		PrintText("You exit the conversation.", "white", True)
	
	EndIf

End Function

Function Response( place$, person$, question$ )

	PrintText(question, "pink", True)

	Select question
	
		Case "How can we get out of here?"
		
			PrintText("This wouldn't be a very good text adventure if I told you that, would it?", "green", True)
			PrintText("Fair enough.", "pink", True)
			DeleteQuestion( place, person, question )	
	
		Case "How you doing?"
		
			PrintText("I'm on death row. How do you expect I'm doing?", "green", True)
			PrintText("I imagine you could be better.", "pink", True)
			DeleteQuestion( place, person, question )
	
		Case "LET ME OUT!"
		
			PrintText("Oi! Keep it shtum in there!", "green", True)
			DeleteQuestion( place, person, question )
			
			q.TQuestion = New TQuestion
			q\Place    = "A"
			q\Person   = "INMATE"
			q\Question = "If I distract the guard, could you take his key?"
		
		Case "If I distract the guard, could you take his key?"
		
			PrintText("Sure thing. Make sure you return the favour though.", "green", True)
			DeleteQuestion( place, person, question )
			
			q.TQuestion = New TQuestion
			q\Place    = "A"
			q\Person   = "GUARD"
			q\Question = "Help! Help!"
			
		Case "Help! Help!"
		
			PrintText("What is it?!", "green", True)
			PrintText("I think I'm bisexual!", "pink", True)
			PrintText("That would explain a lot of things. Now shut up and let me sleep!", "green", True)
			PrintText("During your conversation, the inmate took the key.", "white", True)
			PrintText("The guard walks back to his seat and takes a nap.", "white", True)
			DeleteQuestion( place, person, question )
			
			q.TQuestion = New TQuestion
			q\Place    = "A"
			q\Person   = "INMATE"
			q\Question = "Let's have the key then!"
			
			q.TQuestion = New TQuestion
			q\Place    = "A"
			q\Person   = "INMATE"
			q\Question = "You don't think I'm bisexual, do you?"
			
		Case "Let's have the key then!"
		
			PrintText("Here you go.", "green", True)
			PrintText("The inmate hands you the key.", "white", True)
			PrintText("Cheers mate.", "pink", True)
			DeleteQuestion( place, person, question )
			
			i.TItem = New TItem
			i\Name = "KEY"
			i\Description = "Unlocks your cell."
			
		Case "You don't think I'm bisexual, do you?"
		
			PrintText("We can discuss this later.", "green", True)
			DeleteQuestion( place, person, question )
			
		Case "I'M FREE!"
		
			PrintText("I've helped you get out, now return the favour.", "green", True)
			DeleteQuestion( place, person, question )
		
	End Select

End Function

Function DeleteQuestion( place$, person$, theQuestion$ )

	For question.TQuestion = Each TQuestion
	
		If question\Place = place And question\Person = person And question\Question = theQuestion
		
			Delete question
			
		EndIf
	
	Next

End Function

Function PerformCommand( command$ )

	Select command
	
		Case "QUIT" 			End
		Case "HELP", "H"		Help()
		Case "INVENTORY", "I"	PrintInventory()
		Case "AREA", "A"		PrintArea()
		Case "N"				MoveNorth()
		Case "S"				MoveSouth()
		Case "E"				MoveEast()
		Case "W"				MoveWest()
		Default				
		
			If Left$(command, 8) = "EXAMINE " 
			
				Examine( Right$( command, Len( command ) - 8 ) )
			
			Else
			
				If Left$(command, 5) = "TAKE " 
			
					Take( Right$( command, Len( command ) - 5 ) )
			
				Else
				
					If Left$(command, 4) = "USE " 
			
						Use( Right$( command, Len( command ) - 4 ) )
			
					Else

						If Left$(command, 8) = "TALK TO " 
			
							TalkTo( Right$( command, Len( command ) - 8 ) )
			
						Else

							PrintText("What?", "pink", True)

						EndIf

					EndIf

				EndIf
			
			EndIf
	
	End Select

End Function

Function Help()

	Cls
	Locate 0,0
	
	PrintText("I'm in a dark, damp place.","cyan",True)
	PrintText("Imprisoned for a crime I didn't commit.","cyan",True)
	PrintText("Death row is calling me.","cyan",True)
	PrintText("I need to get out of here.","cyan",True)
	PrintText("","white",True)
	PrintText("JAILBREAK ","yellow",False)
	PrintText("by Ryan Moody","white",True)
	PrintText("","white",True)
	PrintText("Commands can be entered in upper or lowercase.","pink",True)
	PrintText("Keywords that you can perform actions on are highlighted.","pink",True)
	PrintText("","white",True)
	PrintText("Commands:","green",True)
	PrintText("","white",True)
	PrintText("QUIT                       ","yellow",False) : PrintText("- Quits Jailbreak","green",True)
	PrintText("HELP, H                    ","yellow",False) : PrintText("- Displays this page","green",True)
	PrintText("INVENTORY, I               ","yellow",False) : PrintText("- Lists the items you're carrying","green",True)
	PrintText("AREA, A                    ","yellow",False) : PrintText("- Describes the area you're in","green",True)
	PrintText("N, S, E, W                 ","yellow",False) : PrintText("- Move in the chosen compass direction","green",True)
	PrintText("EXAMINE <Object>           ","yellow",False) : PrintText("- Examine an object e.g. EXAMINE APPLE","green",True)
	PrintText("TAKE <Object>              ","yellow",False) : PrintText("- Take an object e.g. TAKE ROPE","green",True)
	PrintText("USE <ObjectA> ON <ObjectB> ","yellow",False) : PrintText("- Use one object on another e.g. USE PEN ON PAPER","green",True)
	PrintText("TALK TO <Person>           ","yellow",False) : PrintText("- Start a conversation with someone e.g. TALK TO JOE","green",True)
	PrintText("","white",True)
	PrintText("Press any key to continue","pink",True)
	
	WaitKey
	Cls
	Locate 0,0 

End Function

Function InitialiseAdventure()
	
	Delete Each TItem
	Delete Each TQuestion
	
	question.TQuestion = New TQuestion
	question\Place    = "A"
	question\Person   = "GUARD"
	question\Question = "LET ME OUT!"
	
	question.TQuestion = New TQuestion
	question\Place    = "A"
	question\Person   = "INMATE"
	question\Question = "How you doing?"
	
	question.TQuestion = New TQuestion
	question\Place    = "A"
	question\Person   = "INMATE"
	question\Question = "How can we get out of here?"

	Restore mapLayout

	For y = 0 To MapDimensions - 1
	
		For x = 0 To MapDimensions - 1
		
			Read Map(x,y)
			
			If Map(x,y) = "A" 
		
				xPos = x
				yPos = y
		
			EndIf
		
		Next
		
	Next

	Help()	
	PrintArea()

End Function

InitialiseAdventure()

While True

	PrintText("Enter a command: ", "yellow", False)
	PerformCommand( Upper$( Input$() ) )

Wend

.mapLayout
Data "#","#","#","#","#","#","#"
Data "#","#","#","#","#","#","#"
Data "#","#","E","#","F","#","#"
Data "#","#","#","A","#","#","#"
Data "#","#","#","#","#","#","#"
Data "#","#","#","#","#","#","#"
Data "#","#","#","#","#","#","#"

Moody Boi's Play Your Cards Right

by Ryan Moody for Workshop #008

If you play it using your telly, instead of your monitor, it's just like you're there on the game!

Click to download this entry

Pumps

by Ryan Moody for Workshop #011

A 2 minute physical challenge (no, it's not rude!).

Cursor Keys

Graphics 800,600
SetBuffer BackBuffer()

Global PumpPosition = 1
Global PumpState = False
Global MovementTimer
Global StartTime

Dim BucketDepths(5)

Function InitialiseBucketDepths()

	For index = 0 To 3
	
		BucketDepths(index) = 0
	
	Next
	
	BucketDepths(4) = 200

End Function

Function UpdateGame()

	FlushKeys

	If MovementTimer + 100 < MilliSecs()
		
		If KeyDown(203) And PumpPosition <> 1
		
			PumpPosition = PumpPosition - 1
			MovementTimer = MilliSecs()
		
		EndIf
		
		If KeyDown(205) And PumpPosition <> 4
		
			PumpPosition = PumpPosition + 1
			MovementTimer = MilliSecs()
		
		EndIf
	
	EndIf
	
	If KeyDown(200) And (Not KeyDown(208)) And (Not PumpState)
	
		PumpState = True
	
	EndIf
	
	If KeyDown(208) And (Not KeyDown(200)) And PumpState
	
		PumpState = False
		
		If PumpPosition = 1
		
			If BucketDepths(1) > 0
		
				BucketDepths(PumpPosition-1) = BucketDepths(PumpPosition-1) + 5
				BucketDepths(PumpPosition) = BucketDepths(PumpPosition) - 5
		
			EndIf
		
		Else
		
			If BucketDepths(PumpPosition) > 0 And BucketDepths(PumpPosition-1) <> (200/(2^(4-(PumpPosition-1)))) 
		
				BucketDepths(PumpPosition-1) = BucketDepths(PumpPosition-1) + 5
				BucketDepths(PumpPosition) = BucketDepths(PumpPosition) - 5
		
			EndIf
				
		EndIf
	
	EndIf

End Function

Function RenderGame()

	Color 255,255,255
	Rect 25,375,50,201,0

	Color 0,0,255
	Rect 26,575-BucketDepths(0),48,BucketDepths(0),1

	For index = 1 To 4
	
		Color 255,255,255
		Rect (175 * index) - 75,375,150,201,0
		Rect (175 * index) - 75,375 + (200/(2^(4-index))),150,200 - (200/(2^(4-index))),1
	
		Color 0,0,255
		Rect (175 * index) - 74,375 + (200/(2^(4-index))) - BucketDepths(index),148,BucketDepths(index),1
	
	Next

	Color 0,0,0
	Line 0,375,800,375
	
	Color 255,255,255
	Text (175 * PumpPosition) - 65,580,"^ PUMP IS HERE ^"
	
	Color 255,255,0
	Rect 35,575-BucketDepths(0)-5,30,5,1
	
	Color 0,255,255
	Oval 40,575-BucketDepths(0)-25,20,20,1
	
	Color 255,0,0
	Oval 40,350,20,20,0
	
	Color 255,0,0
	Text 40,33,"TIME"
	Rect 100,25,675 - (((MilliSecs() - StartTime)/120000.0) * 675),25,1

	If MilliSecs() - StartTime > 120000
	
		SetBuffer FrontBuffer()
		Color 255,255,255
		Text 400,300,"LOCKED IN!",True,True
		Delay 5000
		End
	
	EndIf
	
	If BucketDepths(0) = 200
	
		Flip
		SetBuffer FrontBuffer()
		Color 255,255,255
		Text 400,300,"YOU GOT THE CRYSTAL!",True,True
		Delay 5000
		End
	
	EndIf

End Function

InitialiseBucketDepths()

StartTime = MilliSecs()

While Not KeyDown(1)

	Cls

		RenderGame()

	Flip

	UpdateGame()

Wend